.subckt  TP65H035G4WS 301 302 303

* GROUP A: 301=D1, 302=G1, 303=S1
*
* NODE 000 - 099: RESERVED FOR CAP EMULATION
* NODE 100 - 199: HEMT_A AND NMOS_A
* NODE 300 - 399: PIN AND CONNECTION
*
* Part A: 101=drain A, 152=gate A, 199=source A
* HEMT_A: 101=drainHA, 102=gateHA, 103=sourceHA
* NMOS_A: 151=drainMA, 152=gateMA, 153=sourceMA
*
*   ver 1.0, FEB 04, 2020, By Feng Qi @ Transphorm
*   ver 1.1, JUN 28, 2022, By Ken Shono @ Transphorm
*     CGDA2 is deleted since node 325 no longer exist
*     Bonding wire model is simplified according to ANSYS
*************************************************************************
*The model is an approximation of the device.
*The model may not show the true device performance under all conditions.
*The model only guarantees the accuracy of the key parameters (Ron, Ciss,
*Coss, Crss, Eoss, Qoss, and Qrr) in the current data sheet.
*
*Please refer to the current datasheet for the most up to date specifications
*of the device.
*
*Transphorm Inc. does not assume any liability arising from this use.
*Transphorm Inc. reserves the right to change models without prior notice.
*************************************************************************

************************
***   Part A Begin   ***
************************
* 101=drain A, 152=gate A, 199=source A

**************************
**  Connection A Begin  **

Li1A 103 151 0.01nH
Li2A 102 198 0.01nH
Ri2A 198 153 0.10
Li3A 153 197 0.20nH
Ri3A 197 199 0.01

**  Connection A End  **
************************


*******************
**  HEMT_A Begin **
* xxxx
* 101=drainHA, 102=gateHA, 103=sourceHA


** HEMT_A Body  **

J1A 104 102 103 MJ1A 5.1
.model MJ1A NJF vto -22 beta 1.09 lambda 0.005 rs 0.01
+ cgs 30PF cgd 3.3PF is=1f m=0.3

J2A 105 102 104 MJ2A 5.1
.model MJ2A NJF vto -75 beta 1.09 lambda 0.005
+ cgs 20PF cgd 33PF is=1f m=0.35

J3A 101 102 105 MJ3A 5.1
.model MJ3A NJF vto -210 beta 1.09 lambda 0.005 rd 0.01
+ cgs 10PF cgd 330PF is=1f m=0.4


**  HEMT_A Leakage Compensation  **

DL1A 106 101 MDLA 5.1
DL2A 106 103 MDLA 5.1
.model MDLA D is=0.05uA cjo=0


**  HEMT_A Cap Compensation  **

CJA 101 103 10pF


**  HEMT_A End  **
******************


********************
**  NMOS_A Begin  **
* xxxx
* 151=drainMA, 152=gateMA, 153=sourceMA

MA 159 157 158 158 MMA L=100u W=100u
.MODEL MMA NMOS LEVEL=1 IS=1e-32
+VTO=4.0 LAMBDA=0 KP=63
+CGSO=1.50e-05 CGDO=1.25e-06


DM1A 153 151 MDMA
.MODEL MDMA D IS=2.76e-10 RS=0.002 N=1.2 BV=30
+IBV=0.00025 EG=1.2 XTI=4 TT=4e-09
+CJO=1e-10 VJ=0.82 M=0.5 FC=0.5


RMA  153 151 1e+07
RMDA 159 151 0.0001
RMGA 152 157 2.50174
RMSA 158 153 0.00166991


RMLA 155 160 1
FM2A 157 159 VM2A -1
VM2A 154 0 0
EMA  160 0 159 157 1
CMA  161 160 7.83603e-10
FM1A 157 159 VM1A -1
VM1A 161 156 0
RMCA 156 160 1

DM2A 154 155 MDM1A
.MODEL MDM1A D IS=1e-32 N=50
+CJO=3.05726e-10 VJ=3.40106 M=0.3 FC=1e-08

DM3A 0 155 MDM2A
.MODEL MDM2A D IS=1e-10 N=0.4 RS=3e-06

DM4A 0 156 MDM3A
.MODEL MDM3A D IS=1e-10 N=0.4

**  NMOS_A End  **
******************


**  PartA Cap Compensation  **

CGDA1 321 101 5p
*CGDA2 325 101 5p

*********************
***   PartA End   ***
*********************
*********************



********************************
********************************
***   Pin Connection Begin   ***
********************************


********************
**  301=D1 Begin  **
* from 101=drainA to 301=D1

L315 301 311 4.79n
R315 301 311 2
R311 311 101 1.69m

**  301=D1 End  **
******************


********************
**  302=G1 Begin  **
* from 152=GateA to 302=G1

L320 302 321 6.11n
R320 302 321 5
R321 321 152 6.48m
*
* internal ferrite bead bypassed
* R325 321 326 163
* L325 321 326 270n
* C325 321 326 0.36p
* R326 326 404 0.144
*
**  302=G1 End  **
******************


********************
**  303=S1 Begin  **
* from 199=sourceA to 303=S1

L335 303 331 4.26n
R335 303 331 2
R331 331 199 0.69m

**  303=S1 End  **
******************



******************************
***   Pin Connection End   ***
******************************
******************************


.ends  TP65H035G4WS